class CLUB
-- CLUB is a class for managing membership of a club
   
creation
   make
   
feature   
   members : ARRAY[PERSON]
   
   make is
      local
      do
	 !!members.make(1, 0)   -- start with no members
	 
	 add_new_members
	 
	 print_membership
      end -- make
   
   print_membership is
      local
	 i : INTEGER
      do
	 io.put_new_line
	 io.put_string("THE CLUB"); io.put_new_line
	 io.put_string("--------"); io.put_new_line
	 from i := members.lower
	 until i > members.upper
	 loop
	    members.item(i).print_person
	    io.put_new_line
	    i := i + 1
	 end -- loop
	 io.put_new_line
      end -- print_membership
	 	 
   add_member is
      local
	 p : PERSON
	 aname : STRING
	 atel : INTEGER
      do
	 io.put_string("%NName : ")
	 io.read_line; aname := clone(io.last_string)
	 io.put_string("TelNo : ")
	 io.read_integer; atel := io.last_integer
	 io.skip_remainder_of_line -- needed to get rid of EOL character
	 
	 !!p.make(aname, atel)
	 members.add_last(p)
      end -- add_member
   
   add_new_members is
      local
	 more : BOOLEAN
      do
	 from
	    more := true
	 until
	    not more
	 loop
	    add_member
	    io.put_string("Add another member? [y/n] ")
	    io.read_line
	    if io.last_string.count = 0 or else io.last_string.item(1) /= 'y' 
	     then
	       more := false
	    end -- if
	 end -- loop    
      end -- add_new_members
   
end -- class CLUB